new file mode 100644

@@ -0,0 +1,21 @@

+---

+Checks: >

+    *,

+    -fuchsia-*,

+    # Reduced verbosity,

+    -*-braces-around-statements,

+    -*-implicit-bool-conversion,

+    -*-static-accessed-through-instance,

+    # Interaction with C,

+    -*-cast*,

+    -*-vararg,

+    # Static storage duration throwing constructors,

+    -cert-err58-cpp,

+    # Style,

+    -*-use-trailing-return-type,

+    # Backwards compatibility,

+    -*-union-access,

+    # -Weffc++,

+    -*-redundant-member-init,

+WarningsAsErrors: >

+    *,

new file mode 100644

@@ -0,0 +1 @@

+/build

new file mode 100644

@@ -0,0 +1,176 @@

+## CMake

+cmake_minimum_required(VERSION 3.14)

+

+

+## Project

+set(PROJECT_NAME glfbo3d)

+if ("${CMAKE_PROJECT_NAME}" STREQUAL "${PROJECT_NAME}")

+    return()

+endif()

+project(${PROJECT_NAME}

+    VERSION 1.0.0

+    LANGUAGES CXX

+)

+set(CXX_STANDARD          11)

+set(CXX_STANDARD_REQUIRED ON)

+set(CXX_EXTENSIONS        OFF)

+

+

+## Packages

+find_package(OpenGL REQUIRED)

+find_package(GLEW REQUIRED)

+find_package(glm REQUIRED)

+

+

+## External projects

+include(FetchContent)

+FetchContent_Declare(glshader

+    GIT_REPOSITORY https://git.rcrnstn.net/rcrnstn/glshader

+)

+FetchContent_Declare(gltest

+    GIT_REPOSITORY https://git.rcrnstn.net/rcrnstn/gltest

+)

+FetchContent_MakeAvailable(

+    glshader

+    gltest

+)

+

+

+## Main target

+add_library(${PROJECT_NAME}

+    src/${PROJECT_NAME}.cpp

+    include/${PROJECT_NAME}.hpp

+)

+set_property(TARGET ${PROJECT_NAME} PROPERTY PUBLIC_HEADER

+    include/${PROJECT_NAME}.hpp

+)

+target_include_directories(${PROJECT_NAME}

+    PUBLIC

+        $<INSTALL_INTERFACE:include>

+        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>

+    PRIVATE

+        src

+)

+target_link_libraries(${PROJECT_NAME}

+    PUBLIC

+        OpenGL::GL

+        GLEW::GLEW

+)

+

+

+if ("${CMAKE_PROJECT_NAME}" STREQUAL "${PROJECT_NAME}")

+

+

+    ## Test target

+    add_executable(${PROJECT_NAME}-test

+        tests/${PROJECT_NAME}.cpp

+    )

+    target_include_directories(${PROJECT_NAME}-test

+        PRIVATE

+            tests

+    )

+    target_link_libraries(${PROJECT_NAME}-test

+        PRIVATE

+            ${PROJECT_NAME}

+            OpenGL::GL

+            GLEW::GLEW

+            glm

+            glshader

+            gltest

+    )

+    add_test(

+        NAME    ${PROJECT_NAME}-test

+        COMMAND ${PROJECT_NAME}-test

+        WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}

+    )

+

+

+    ## Default build type for single-configuration generators

+    if (NOT CMAKE_BUILD_TYPE)

+        set(CMAKE_BUILD_TYPE Debug)

+    endif()

+

+

+    ## Language tools and options

+    set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

+    find_program(CPPCHECK             cppcheck)

+    find_program(CLANG_TIDY           clang-tidy)

+    find_program(INCLUDE_WHAT_YOU_USE include-what-you-use)

+    if(CPPCHECK)

+        set(CXX_CPPCHECK ${CPPCHECK} --enable=warning,style --error-exitcode=1)

+    endif()

+    if(CLANG_TIDY)

+        set(CXX_CLANG_TIDY ${CLANG_TIDY})

+    endif()

+    if(INCLUDE_WHAT_YOU_USE)

+        set(CXX_INCLUDE_WHAT_YOU_USE ${INCLUDE_WHAT_YOU_USE})

+    endif()

+    if (MSVC)

+        set(COMPILE_OPTIONS

+            /permissive-

+            /WX

+            /W4

+        )

+    elseif ("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU|.*Clang")

+        set(COMPILE_OPTIONS

+            -pedantic

+            -Werror -Wfatal-errors

+            -Wall -Wextra

+            -Wconversion -Wsign-conversion

+            -Wdouble-promotion

+            -Wimplicit-fallthrough

+            -Wvla

+            -Wzero-as-null-pointer-constant

+            -Weffc++

+        )

+        set(SANITIZE_OPTIONS

+            $<$<CONFIG:Debug>:-fsanitize=address,leak,undefined>

+        )

+        list(APPEND COMPILE_OPTIONS ${SANITIZE_OPTIONS})

+        list(APPEND LINK_OPTIONS    ${SANITIZE_OPTIONS})

+    endif()

+    include(CheckIPOSupported)

+    check_ipo_supported(RESULT INTERPROCEDURAL_OPTIMIZATION)

+    get_directory_property(BUILDSYSTEM_TARGETS BUILDSYSTEM_TARGETS)

+    set_target_properties(

+        ${BUILDSYSTEM_TARGETS}

+        PROPERTIES

+            CXX_STANDARD             "${CXX_STANDARD}"

+            CXX_STANDARD_REQUIRED    "${CXX_STANDARD_REQUIRED}"

+            CXX_EXTENSIONS           "${CXX_EXTENSIONS}"

+            CXX_CPPCHECK             "${CXX_CPPCHECK}"

+            CXX_CLANG_TIDY           "${CXX_CLANG_TIDY}"

+            CXX_INCLUDE_WHAT_YOU_USE "${CXX_INCLUDE_WHAT_YOU_USE}"

+            COMPILE_OPTIONS          "${COMPILE_OPTIONS}"

+            LINK_OPTIONS             "${LINK_OPTIONS}"

+            INTERPROCEDURAL_OPTIMIZATION

+                "${INTERPROCEDURAL_OPTIMIZATION}"

+    )

+

+

+    ## Testing

+    include(CTest)

+

+

+    ## Packaging and installing

+    include(CPack)

+    install(TARGETS ${PROJECT_NAME} EXPORT ${PROJECT_NAME})

+    include(GNUInstallDirs)

+    set(CMAKE_INSTALL_CMAKEDIR ${CMAKE_INSTALL_LIBDIR}/cmake

+        CACHE PATH "System CMake package config files"

+    )

+    install(EXPORT ${PROJECT_NAME}

+        FILE ${PROJECT_NAME}Config.cmake

+        DESTINATION ${CMAKE_INSTALL_CMAKEDIR}/${PROJECT_NAME}

+    )

+    include(CMakePackageConfigHelpers)

+    write_basic_package_version_file(${PROJECT_NAME}ConfigVersion.cmake

+        COMPATIBILITY SameMajorVersion

+    )

+    install(

+        FILES ${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake

+        DESTINATION ${CMAKE_INSTALL_CMAKEDIR}/${PROJECT_NAME}

+    )

+

+

+endif()

@@ -10,6 +10,112 @@ A [C++11][] test of [OpenGL][] \>=3.2 3D [Framebuffer Objects (FBOs)][].

 [OpenGL]: https://www.opengl.org

 [Framebuffer Objects (FBOs)]: https://www.khronos.org/opengl/wiki/Framebuffer_Object

+## Dependencies

+

+Private (tests):

+

+-   [OpenGL][], system (e.g. [`libgl1-mesa-dev`][]).

+-   [OpenGL Extension Wrangler (GLEW)][], system (e.g. [`libglew-dev`][]).

+-   [OpenGL Mathematics (GLM)][], system (e.g. [`libglm-dev`][]).

+-   [`glshader`][], downloaded as part of the CMake configure step.

+-   [`gltest`][], downloaded as part of the CMake configure step.

+

+Private (transitive):

+

+-   [GLFW][], system (e.g. [`libglfw3-dev`][]).

+-   [`str`][], downloaded as part of the CMake configure step.

+

+[OpenGL Extension Wrangler (GLEW)]: http://glew.sourceforge.net

+[OpenGL Mathematics (GLM)]: https://glm.g-truc.net

+[GLFW]: https://www.glfw.org

+[`libgl1-mesa-dev`]: https://packages.debian.org/search?keywords=libgl1-mesa-dev

+[`libglew-dev`]: https://packages.debian.org/search?keywords=libglew-dev

+[`libglm-dev`]: https://packages.debian.org/search?keywords=libglm-dev

+[`libglfw3-dev`]: https://packages.debian.org/search?keywords=libglfw3-dev

+[`glshader`]: https://git.rcrnstn.net/rcrnstn/glshader

+[`gltest`]: https://git.rcrnstn.net/rcrnstn/gltest

+[`str`]: https://git.rcrnstn.net/rcrnstn/str

+

+## Build system

+

+There are several ways to use this library in a [CMake][]-based project:

+

+-   Use [`FetchContent`][] to download it and import the targets automatically

+    as part of the configure step:

+

+    ```cmake

+    include(FetchContent)

+    FetchContent_Declare(glfbo3d

+        GIT_REPOSITORY https://git.rcrnstn.net/rcrnstn/glfbo3d

+    )

+    FetchContent_MakeAvailable(

+        glfbo3d

+    )

+    ```

+

+-   Bundle it and import the targets with [`add_subdirectory`][].

+

+-   Use [`find_package`][] (requires that the library is [packaged](#packaging)

+    or [installed](#installing)).

+

+As usual, use [`target_link_libraries`][] to declare the dependency.

+

+[CMake]: https://cmake.org

+[`FetchContent`]: https://cmake.org/cmake/help/latest/module/FetchContent.html

+[`add_subdirectory`]: https://cmake.org/cmake/help/latest/command/add_subdirectory.html

+[`find_package`]: https://cmake.org/cmake/help/latest/command/find_package.html

+[`target_link_libraries`]: https://cmake.org/cmake/help/latest/command/target_link_libraries.html

+

+### Configure and generate

+

+To configure and generate a build tree, use `cmake`:

+

+```sh

+cmake -B build

+```

+

+[`cmake`]: https://cmake.org/cmake/help/latest/manual/cmake.1.html#generate-a-project-buildsystem

+

+### Build

+

+To build, use [`cmake --build`][]:

+

+```sh

+cmake --build build

+```

+

+[`cmake --build`]: https://cmake.org/cmake/help/latest/manual/cmake.1.html#build-a-project

+

+### Test

+

+To run tests, use [`ctest`][]:

+

+```sh

+(cd build && ctest --verbose)

+```

+

+[`ctest`]: https://cmake.org/cmake/help/latest/manual/ctest.1.html

+

+### Package

+

+To package, use [`cpack`][]:

+

+```sh

+(cd build && cpack)

+```

+

+[`cpack`]: https://cmake.org/cmake/help/latest/manual/cpack.1.html

+

+### Install

+

+To install onto the current system, use [`cmake --install`][]:

+

+```sh

+cmake --install build

+```

+

+[`cmake --install`]: https://cmake.org/cmake/help/latest/manual/cmake.1.html#install-a-project

+

 ## License

 Licensed under the [ISC license][] unless otherwise noted, see the

new file mode 100644

new file mode 100644

new file mode 100644