new file mode 100644

@@ -0,0 +1,62 @@

+---

+

+WarningsAsErrors: >

+    # All,

+    *,

+

+Checks: >

+    # All,

+    *,

+

+    # Company/project-specific,

+    -google-*,

+    -llvm-*,

+    -llvmlibc-*,

+    -fuchsia-*,

+    -altera-*,

+

+    # Extra command line arguments,

+    -clang-diagnostic-unknown-warning-option,

+    -clang-diagnostic-ignored-optimization-argument,

+

+    # "Consider",

+    -cppcoreguidelines-avoid-non-const-global-variables,

+

+    # Style,

+    -*-use-trailing-return-type,

+    -*-container-size-empty,

+    -*-easily-swappable-parameters,

+    -*-return-braced-init-list,

+    -*-non-private-member-variables-in-classes,

+    -*-magic-numbers,

+

+    # Verbosity,

+    -*-braces-around-statements,

+    -*-implicit-bool-conversion,

+    -*-static-accessed-through-instance,

+    -*-named-parameter,

+

+    # -Weffc++,

+    -*-redundant-member-init,

+

+    # Interaction with C,

+    -*-cast*,

+    -*-vararg,

+    -*array-*decay,

+

+    # Backwards compatibility,

+    -*-union-access,

+

+    # Static storage duration throwing constructors,

+    -cert-err58-cpp,

+

+    # Complex functions,

+    -*readability-function-cognitive-complexity,

+

+    # Macro magic,

+    -*-macro-usage,

+    -*bugprone-macro-parentheses,

+    -*bugprone-lambda-function-name,

+

+    # Exceptions,

+    -*bugprone-exception-escape,

new file mode 100644

@@ -0,0 +1 @@

+shadowFunction

new file mode 100644

@@ -0,0 +1 @@

+/_build

new file mode 100644

@@ -0,0 +1,94 @@

+# Building

+

+This project supports [CMake][] and uses [`cmake-common`][]. There are several

+ways to use it in other CMake-based projects:

+

+-   With [`find_package`][]: ([Package][] and) [install][] it on the system.

+

+-   With [`add_subdirectory`][]: Bundle it.

+

+-   With [`FetchContent`][]: Download it as part of the CMake configure step.

+

+-   With [`cmake-common`][]: Use any of the above methods through a simplified

+    interface.

+

+As usual, use [`add_dependencies`][] or [`target_link_libraries`][] (or

+`cmake-common`'s `DEPENDENCIES_*`) to declare the dependency.

+

+[CMake]: https://cmake.org

+[`cmake-common`]: https://git.rcrnstn.net/rcrnstn/cmake-common

+[`FetchContent`]: https://cmake.org/cmake/help/v3.14/module/FetchContent.html

+[`add_subdirectory`]: https://cmake.org/cmake/help/v3.14/command/add_subdirectory.html

+[`find_package`]: https://cmake.org/cmake/help/v3.14/command/find_package.html

+[Package]: #Package

+[Install]: #Install

+[`add_dependencies`]: https://cmake.org/cmake/help/v3.14/command/add_dependencies.html

+[`target_link_libraries`]: https://cmake.org/cmake/help/v3.14/command/target_link_libraries.html

+

+## Configure and generate

+

+To configure and generate a build tree, use [`cmake`][]:

+

+```sh

+cmake -B _build

+```

+

+To set the build type, pass e.g. `-D`[`CMAKE_BUILD_TYPE`][]`=Release`.

+

+To disable building tests, pass `-D`[`BUILD_TESTING`][]`=OFF`.

+

+[`cmake`]: https://cmake.org/cmake/help/v3.14/manual/cmake.1.html#generate-a-project-buildsystem

+[`CMAKE_BUILD_TYPE`]: https://cmake.org/cmake/help/v3.14/variable/CMAKE_BUILD_TYPE.html

+[`BUILD_TESTING`]: https://cmake.org/cmake/help/v3.14/module/CTest.html

+

+## Build

+

+To build, use [`cmake --build`][]:

+

+```sh

+cmake --build _build

+```

+

+To build in parallel with native build tools that do not do this by default

+(such as [GNU Make][]), pass `--parallel` followed by the number of concurrent

+processes to use, e.g. `$(`[`nproc`][]`)`.

+

+[`cmake --build`]: https://cmake.org/cmake/help/v3.14/manual/cmake.1.html#build-a-project

+[GNU Make]: https://www.gnu.org/software/make/

+[`nproc`]: https://www.gnu.org/software/coreutils/manual/html_node/nproc-invocation.html

+

+## Test

+

+To run tests, use [`ctest`][]:

+

+```sh

+(cd _build && ctest)

+```

+

+To show output from failing tests, pass `--output-on-failure`. To show output

+from all tests, pass `--verbose`.

+

+[`ctest`]: https://cmake.org/cmake/help/v3.14/manual/ctest.1.html

+

+## Package

+

+To package, use [`cpack`][]:

+

+```sh

+(cd _build && cpack)

+```

+

+[`cpack`]: https://cmake.org/cmake/help/v3.14/manual/cpack.1.html

+

+## Install

+

+To install onto the current system, use [`cmake --install`][]:

+

+```sh

+cmake --install _build

+```

+

+To set the prefix, pass e.g. `-D`[`CMAKE_INSTALL_PREFIX`][]`="$HOME/.local"`.

+

+[`cmake --install`]: https://cmake.org/cmake/help/v3.14/manual/cmake.1.html#install-a-project

+[`CMAKE_INSTALL_PREFIX`]: https://cmake.org/cmake/help/v3.14/variable/CMAKE_INSTALL_PREFIX.html

@@ -2,6 +2,13 @@

 A [CMake][]\>=3.14 [C++][] common project helper.

+[CMake][] has many useful features but requires verbose per-project

+configuration to enable them. This helper allows you to just place your files

+where everyone expects them to be anyway, install the tools you want to use,

+and things like downloading dependencies, linting, building, testing,

+sanitizing, packaging (build artifacts, assets, documentation), and installing

+will automatically be enabled.

+

 [`cmake-common`]: https://git.rcrnstn.net/rcrnstn/cmake-common

 [CMake]: https://cmake.org

 [C++]: https://en.wikipedia.org/wiki/C++

@@ -14,11 +21,281 @@ this work is to simply copy the required files or content into your project,

 optionally(!) mentioning where it came from in the readme or other

 documentation. See [License][].

+Copy the file [`common.cmake`][] into your project and [`include`][] it from

+(e.g.) the main [`CMakeLists.txt`][]. This will define a `common` function that

+takes a number of arguments to configure the project.

+

 [License]: #license

+[`include`]: https://cmake.org/cmake/help/v3.14/command/include.html

+[`common.cmake`]: common.cmake

+[`CMakeLists.txt`]: https://cmake.org/cmake/help/v3.14/manual/cmake-language.7.html#directories

+

+### Overview

+

+```cmake

+## CMake

+cmake_minimum_required(VERSION 3.14)

+if(NOT CMAKE_BUILD_TYPE)

+    set(CMAKE_BUILD_TYPE Debug)

+endif()

+

+## Project

+project(project-name

+    VERSION 1.0.0

+    LANGUAGES CXX

+)

+

+## Main target

+add_library(${PROJECT_NAME})

+

+## Common

+include(common.cmake)

+common(

+    CXX_STANDARD 11

+    DISABLE_INCLUDE_WHAT_YOU_USE

+    PACKAGES

+        Package

+    EXTERNAL

+        external_project

+    FETCHCONTENT

+        "https://example.com/user/online_project GIT_TAG v1.2.3"

+    DEPENDENCIES_PUBLIC

+        Package::Package

+    DEPENDENCIES_PRIVATE

+        external_project

+    DEPENDENCIES_TESTS

+        online_project

+    DEFINITIONS

+        PROJECT_FEATURE

+)

+```

+

+### Main target

+

+If there are files in the `src` and/or `include` directories, they are added as

+sources to a single "main" target, which is assumed to already be declared with

+the name `${`[`PROJECT_NAME`][]`}` (which is automatically set by CMake when

+calling [`project`][]). The "main" target may be of any type, such as [normal

+executable][], [normal library][], [interface library][], or [custom target][]

+(the latter probably with the `ALL` specifier, so that it is added to the

+default build target so that it will be run every time).

+

+[`PUBLIC`][] dependencies are taken from `DEPENDENCIES_PUBLIC` and

+[`PRIVATE`][] dependencies are taken from `DEPENDENCIES_PRIVATE`, see

+[Dependencies][].

+

+For [top level project][]s, `*Config.cmake` and `*ConfigVersion.cmake` files

+that can be used by [`find_package`][] to find this project are

+[`install`][]ed, see [Packaging][].

+

+[`PROJECT_NAME`]: https://cmake.org/cmake/help/v3.14/variable/PROJECT_NAME.html

+[`project`]: https://cmake.org/cmake/help/v3.14/command/project.html

+[normal executable]: https://cmake.org/cmake/help/v3.14/command/add_executable.html#normal-executables

+[normal library]: https://cmake.org/cmake/help/v3.14/command/add_library.html#normal-libraries

+[interface library]: https://cmake.org/cmake/help/v3.14/command/add_library.html#interface-libraries

+[custom target]: https://cmake.org/cmake/help/v3.14/command/add_custom_target.html

+[`PUBLIC`]: https://cmake.org/cmake/help/v3.14/manual/cmake-buildsystem.7.html#target-usage-requirements

+[`PRIVATE`]: https://cmake.org/cmake/help/v3.14/manual/cmake-buildsystem.7.html#target-usage-requirements

+[Dependencies]: #dependencies

+[top level project]: https://cmake.org/cmake/help/v3.14/variable/CMAKE_PROJECT_NAME.html

+[`find_package`]: https://cmake.org/cmake/help/v3.14/command/find_package.html

+[`install`]: https://cmake.org/cmake/help/v3.14/command/install.html

+[Packaging]: #packaging

+

+### Test targets

+

+For [top level project][]s, every file directly under the `tests` directory is

+individually added as a source to a separate executable "test" target, which is

+automatically declared with the name `${PROJECT_NAME}-test-${TEST_NAME}` and

+passed to [`add_test`][]. All files in the `tests/common` directory are also

+added as sources to all "test" targets.

+

+A ([`PRIVATE`][]) dependency on the "main" target is declared and further

+([`PRIVATE`][]) dependencies are taken from `DEPENDENCIES_TESTS`, see

+[Dependencies][].

+

+CMake can be run with the standard `-D`[`BUILD_TESTING`][]`=OFF` to disable

+testing.

+

+See [Testing][].

+

+[`add_test`]: https://cmake.org/cmake/help/v3.14/command/add_test.html

+[`BUILD_TESTING`]: https://cmake.org/cmake/help/v3.14/module/CTest.html

+[Testing]: #testing

+

+### Assets

+

+If there are files in the `assets` directory, a target named

+`${PROJECT_NAME}-assets` that runs by default and [symlink][]s them to

+`${`[`CMAKE_BINARY_DIR`][]`}/assets` is automatically declared.

+

+If the path does not include `/tests/`, the asset is [`install`][]ed into

+`${`[`CMAKE_INSTALL_DATADIR`][]`}/${CMAKE_PROJECT_NAME}/assets` (note that

+`CMAKE_PROJECT_NAME` is the name of the [top level project][]), see

+[Packaging][].

+

+[symlink]: https://en.wikipedia.org/wiki/Symbolic_link

+[`CMAKE_BINARY_DIR`]: https://cmake.org/cmake/help/v3.14/variable/CMAKE_BINARY_DIR.html

+[`CMAKE_INSTALL_DATADIR`]: https://cmake.org/cmake/help/v3.14/module/GNUInstallDirs.html

+

+### Documentation

+

+For [top level project][]s, documentation from the `doc` directory and

+repository root is automatically [`install`][]ed, see [Packaging][].

+

+### Man pages

+

+For [top level project][]s, [man page][]s from the `man` directory is

+automatically [`install`][]ed, see [Packaging][].

+

+[man page]: https://en.wikipedia.org/wiki/Man_page

+

+### Dependencies

+

+Dependencies on other targets are declared with `DEPENDENCIES_PUBLIC`,

+`DEPENDENCIES_PRIVATE`, and `DEPENDENCIES_TESTS`, see [Main target][] and [Test

+targets][].

+

+Three mechanisms to make these dependencies available are provided, given as

+arguments to the `common` function:

+

+-   `PACKAGES`: Packages passed to [`find_package`][]`(...)` in order to find

+    system packages.

+-   `EXTERNAL`: Subdirectories of `external` that is passed to

+    [`add_subdirectory`][].

+-   `FETCHCONTENT`: [Git][] [URL][]s passed to [`FetchContent_Declare`][]'s

+    `GIT_REPOSITORY`. If a specific [Git tag][] is wanted, specify it in the

+    same (quoted) argument, delimited with `GIT_TAG`, see [Usage][].

+    (`GIT_SHALLOW` and `GIT_PROGRESS` are always set to `TRUE`).

+    [`FetchContent_MakeAvailable`][] is automatically called in order to

+    download and make targets available during the CMake configure step.

+

+If more involved steps are required to make targets available, perform them

+manually before calling the `common` function.

+

+[Main target]: #main-target

+[Test targets]: #test-targets

+[`add_subdirectory`]: https://cmake.org/cmake/help/v3.14/command/add_subdirectory.html

+[Git]: https://git-scm.com

+[URL]: https://en.wikipedia.org/wiki/URL

+[`FetchContent_Declare`]: https://cmake.org/cmake/help/v3.14/module/FetchContent.html#command:fetchcontent_declare

+[`FetchContent_MakeAvailable`]: https://cmake.org/cmake/help/v3.14/module/FetchContent.html#command:fetchcontent_makeavailable

+[Git tag]: https://git-scm.com/book/en/v2/Git-Basics-Tagging

+[Usage]: #usage

+

+### Preprocessor definitions

+

+[Preprocessor definitions][] can be specified with the `DEFINITIONS` argument

+to the `common` function. Both `NAME` and `NAME=EXPANSION` forms are supported.

+

+[preprocessor definitions]: https://en.cppreference.com/w/cpp/preprocessor/replace#.23define_directives

+

+### Language version

+

+For [top level project][]s, the `CXX_STANDARD` argument to the `common`

+function sets the [`CXX_STANDARD`][] property applied to configured targets

+([`CXX_STANDARD_REQUIRED`][] is always set to `ON`, [`CXX_EXTENSIONS`][] is

+always set to `OFF`).

+

+[`CXX_STANDARD`]: https://cmake.org/cmake/help/v3.14/prop_tgt/CXX_STANDARD.html

+[`CXX_STANDARD_REQUIRED`]: https://cmake.org/cmake/help/v3.14/prop_tgt/CXX_STANDARD_REQUIRED.html

+[`CXX_EXTENSIONS`]: https://cmake.org/cmake/help/v3.14/prop_tgt/CXX_EXTENSIONS.html

+

+### Build options

+

+For [top level project][]s, aggressive warnings are enabled and treated as

+errors.

+

+For projects compiled with [GCC][] or [Clang][], [`-Wshadow`][] is enabled by

+default, but can be disabled by passing `DISABLE_WSHADOW` to the `common`

+function.

+

+For projects compiled with [MSVC][], [`/Zc:__cplusplus`][] is enabled.

+

+If supported, [interprocedural optimization][] (also known as link-time

+optimization) is enabled.

+

+For projects compiled with the `Debug` [build type][] with [GCC][] or

+[Clang][], [address sanitizer][] ([wiki][address sanitizer wiki]), [leak

+sanitizer][] ([wiki][leak sanitizer wiki]), and [undefined behavior

+sanitizer][] are linked into all targets. The sanitizers can be disabled by

+passing `DISABLE_SANITIZERS` to the `common` function. Suppression files that

+match the [glob][]s `*.asan.supp`, `*.lsan.supp`, and `*.ubsan.supp`

+respectively in the repository root are automatically used.

+

+[GCC]: https://gcc.gnu.org

+[Clang]: https://clang.llvm.org

+[`-Wshadow=`]: https://gcc.gnu.org/onlinedocs/gcc/Warning-Options.html#index-Wshadow

+[MSVC]: https://visualstudio.microsoft.com/vs/

+[`/Zc:__cplusplus`]: https://learn.microsoft.com/en-us/cpp/build/reference/zc-cplusplus

+[interprocedural optimization]: https://en.wikipedia.org/wiki/Interprocedural_optimization

+[build type]: https://cmake.org/cmake/help/v3.14/variable/CMAKE_BUILD_TYPE.html

+[address sanitizer]: https://clang.llvm.org/docs/AddressSanitizer.html

+[address sanitizer wiki]: https://github.com/google/sanitizers/wiki/AddressSanitizer

+[leak sanitizer]: https://clang.llvm.org/docs/LeakSanitizer.html

+[leak sanitizer wiki]: https://github.com/google/sanitizers/wiki/AddressSanitizerLeakSanitizer

+[undefined behavior sanitizer]: https://clang.llvm.org/docs/UndefinedBehaviorSanitizer.html

+[glob]: https://en.wikipedia.org/wiki/Glob_(programming)

+

+### Tools

+

+For [top level project][]s compiled with the `Debug` [build type][],

+[Cppcheck][], [Clang-Tidy][], and [Include What You Use][] are automatically

+configured if present on the system. The tools can be disabled by passing the

+`DISABLE_CPPCHECK`, `DISABLE_CLANG_TIDY`, and/or `DISABLE_INCLUDE_WHAT_YOU_USE`

+options, respectively, to the `common` function. CppCheck suppressions list

+files that match the [glob][] `.cppcheck.supp`, a Clang-Tidy configuration file

+named `.clang-tidy`, and Include What You Use [mapping files][] that match the

+[glob][] `*.iwyu.imp`, in the repository root, are automatically used.

+

+[Cppcheck]: https://cppcheck.sourceforge.io

+[Clang-Tidy]: https://clang.llvm.org/extra/clang-tidy

+[Include What You Use]: https://include-what-you-use.org

+[mapping files]: https://github.com/include-what-you-use/include-what-you-use/blob/0.20/docs/IWYUMappings.md

+

+### Testing

+

+For [top level project][]s, [CTest][] is automatically configured and can be

+run with [`ctest`][], see the [`BUILDING.md`][] auxiliary file.

+

+[CTest]: https://cmake.org/cmake/help/v3.14/module/CTest.html

+[`ctest`]: https://cmake.org/cmake/help/v3.14/manual/ctest.1.html

+[`BUILDING.md`]: BUILDING.md

+

+### Packaging

+

+For [top level project][]s, [CPack][] is automatically configured and can be

+run with [`cpack`][], see the [`BUILDING.md`][] auxiliary file.

+

+[CPack]: https://cmake.org/cmake/help/v3.14/module/Pack.html

+[`cpack`]: ttps://cmake.org/cmake/help/v3.14/manual/cpack.1.html

+

+## Auxiliary files

+

+This repository includes some files besides [`common.cmake`][] that may be of

+use:

+

+-   [`BUILDING.md`][]: Instructions to build a project that uses

+    [`cmake-common`][].

+

+-   [`.gitignore`][]: A configuration file for [Git][] that makes it ignore the

+    created `_build` directory created when following the instructions in

+    [`BUILDING.md`][].

+

+-   [`.cppcheck.supp`][]: A suppressions list for [CppCheck][] with a set of

+    suppressed warnings.

+

+-   [`.clang-tidy`][]: A configuration file for [Clang-Tidy][] with a set of

+    enabled and disabled warnings.

+

+[`.gitignore`]: .gitignore

+[`.cppcheck.supp`]: .cppcheck.supp

+[`.clang-tidy`]: .clang-tidy

 ## License

 Licensed under the [BSD 0-Clause License][] unless otherwise noted, see the

-[`LICENSE`](LICENSE) file.

+[`LICENSE`][] file.

 [BSD 0-Clause License]: https://choosealicense.com/licenses/0bsd/

+[`LICENSE`]: LICENSE

new file mode 100644

@@ -0,0 +1,427 @@

+# https://git.rcrnstn.net/rcrnstn/cmake-common

+

+## CMake modules

+include(FetchContent)

+include(CMakePackageConfigHelpers)

+include(CheckIPOSupported)

+include(GNUInstallDirs)

+include(CTest)

+if(NOT CPack_CMake_INCLUDED)

+    include(CPack)

+endif()

+

+function(common)

+    ## Arguments

+    set(OPTIONS

+        DISABLE_WSHADOW

+        DISABLE_SANITIZERS

+        DISABLE_CPPCHECK

+        DISABLE_CLANG_TIDY

+        DISABLE_INCLUDE_WHAT_YOU_USE

+    )

+    set(ONE_VALUE_ARGS

+        CXX_STANDARD

+    )

+    set(MULTI_VALUE_ARGS

+        PACKAGES

+        EXTERNAL

+        FETCHCONTENT

+        DEPENDENCIES_PUBLIC

+        DEPENDENCIES_PRIVATE

+        DEPENDENCIES_TESTS

+        DEFINITIONS

+    )

+    cmake_parse_arguments(PARSE_ARGV 0 ARG

+        "${OPTIONS}"

+        "${ONE_VALUE_ARGS}"

+        "${MULTI_VALUE_ARGS}"

+    )

+

+    ## Variables

+    set(PROJECT_IS_TOP_LEVEL)

+    set(PROJECT_IS_INTERFACE_LIBRARY)

+    set(PROJECT_IS_DEBUG)

+    get_target_property(PROJECT_TYPE ${PROJECT_NAME} TYPE)

+    string(TOLOWER "${CMAKE_BUILD_TYPE}" PROJECT_BUILD_TYPE)

+    if("${CMAKE_PROJECT_NAME}" STREQUAL "${PROJECT_NAME}")

+        set(PROJECT_IS_TOP_LEVEL TRUE)

+    endif()

+    if("${PROJECT_TYPE}" STREQUAL "INTERFACE_LIBRARY")

+        set(PROJECT_IS_INTERFACE_LIBRARY TRUE)

+    endif()

+    if("${PROJECT_BUILD_TYPE}" STREQUAL "debug")

+        set(PROJECT_IS_DEBUG TRUE)

+    endif()

+

+    ## Packages

+    foreach(PACKAGE ${ARG_PACKAGES})

+        find_package(${PACKAGE})

+    endforeach()

+

+    ## External

+    foreach(EXTERNAL ${ARG_EXTERNAL})

+        add_subdirectory(external/${EXTERNAL} EXCLUDE_FROM_ALL)

+    endforeach()

+

+    ## FetchContent

+    foreach(FETCHCONTENT ${ARG_FETCHCONTENT})

+        get_filename_component(FETCHCONTENT_NAME ${FETCHCONTENT} NAME)

+        FetchContent_Declare(${FETCHCONTENT_NAME}

+            GIT_REPOSITORY ${FETCHCONTENT}

+            GIT_SHALLOW TRUE

+            GIT_PROGRESS TRUE

+        )

+        FetchContent_MakeAvailable(${FETCHCONTENT_NAME})

+    endforeach()

+

+    ## Main target

+    target_compile_definitions(${PROJECT_NAME} PUBLIC ${ARG_DEFINITIONS})

+    file(GLOB_RECURSE SRC CONFIGURE_DEPENDS

+        RELATIVE "${PROJECT_SOURCE_DIR}"

+        src/*

+    )

+    file(GLOB_RECURSE INCLUDE CONFIGURE_DEPENDS

+        RELATIVE "${PROJECT_SOURCE_DIR}"

+        include/*

+    )

+    if(NOT ("${SRC}" STREQUAL "" AND "${INCLUDE}" STREQUAL ""))

+        if(PROJECT_IS_INTERFACE_LIBRARY)

+            target_include_directories(${PROJECT_NAME}

+                INTERFACE

+                    "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>"

+                    "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"

+            )

+        else()

+            target_sources(${PROJECT_NAME}

+                PRIVATE

+                    ${SRC}

+                    ${INCLUDE}

+            )

+            target_include_directories(${PROJECT_NAME}

+                PUBLIC

+                    "$<BUILD_INTERFACE:${PROJECT_SOURCE_DIR}/include>"

+                    "$<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>"

+                PRIVATE

+                    src

+            )

+            target_link_libraries(${PROJECT_NAME}

+                PUBLIC

+                    ${ARG_DEPENDENCIES_PUBLIC}

+                PRIVATE

+                    "$<BUILD_INTERFACE:${ARG_DEPENDENCIES_PRIVATE}>"

+            )

+        endif()

+        if(PROJECT_IS_TOP_LEVEL)

+            install(

+                DIRECTORY

+                    include/

+                DESTINATION

+                    ${CMAKE_INSTALL_INCLUDEDIR}

+            )

+            install(TARGETS ${PROJECT_NAME} EXPORT ${PROJECT_NAME})

+            install(EXPORT ${PROJECT_NAME}

+                FILE ${PROJECT_NAME}Config.cmake

+                DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}

+            )

+            write_basic_package_version_file(${PROJECT_NAME}ConfigVersion.cmake

+                COMPATIBILITY SameMajorVersion

+            )

+            install(

+                FILES ${PROJECT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake

+                DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}

+            )

+        endif()

+    endif()

+

+    ## Test targets

+    set(TEST_TARGETS)

+    if(PROJECT_IS_TOP_LEVEL AND BUILD_TESTING)

+        file(GLOB_RECURSE TESTS_COMMON CONFIGURE_DEPENDS

+            tests/common/*

+        )

+        file(GLOB TESTS CONFIGURE_DEPENDS

+            LIST_DIRECTORIES FALSE

+            tests/*

+        )

+        foreach(TEST ${TESTS})

+            get_filename_component(TEST_NAME "${TEST}" NAME_WE)

+            set(TEST_TARGET "${PROJECT_NAME}-test-${TEST_NAME}")

+            add_executable(${TEST_TARGET}

+                ${TEST}

+                ${TESTS_COMMON}

+            )

+            target_include_directories(${TEST_TARGET}

+                PRIVATE

+                    tests

+            )

+            target_link_libraries(${TEST_TARGET}

+                PRIVATE

+                    ${PROJECT_NAME}

+                    ${ARG_DEPENDENCIES_TESTS}

+            )

+            add_test(

+                NAME    ${TEST_TARGET}

+                COMMAND ${TEST_TARGET}

+            )

+            list(APPEND TEST_TARGETS ${TEST_TARGET})

+        endforeach()

+    endif()

+

+    ## Build targets

+    set(BUILD_TARGETS ${TEST_TARGETS})

+    if(NOT PROJECT_IS_INTERFACE_LIBRARY)

+        list(APPEND BUILD_TARGETS ${PROJECT_NAME})

+    endif()

+

+    ## Assets

+    file(REMOVE_RECURSE

+        ${CMAKE_BINARY_DIR}/assets

+    )

+    file(GLOB_RECURSE ASSETS CONFIGURE_DEPENDS

+        RELATIVE "${PROJECT_SOURCE_DIR}"

+        assets/*

+    )

+    if(NOT "${ASSETS}" STREQUAL "")

+        add_custom_target(${PROJECT_NAME}-assets)

+        add_dependencies(${PROJECT_NAME} ${PROJECT_NAME}-assets)

+    endif()

+    foreach(ASSET ${ASSETS})

+        get_filename_component(ASSET_DIR ${ASSET} DIRECTORY)

+        if("${ASSET}" MATCHES "/tests/")

+            set(ASSET_TEST TRUE)

+        else()

+            set(ASSET_TEST FALSE)

+        endif()

+        if(ASSET_TEST AND NOT PROJECT_IS_TOP_LEVEL)

+            continue()

+        endif()

+        add_custom_command(

+            DEPENDS

+                ${PROJECT_SOURCE_DIR}/${ASSET}

+            OUTPUT

+                ${CMAKE_BINARY_DIR}/${ASSET}

+            COMMAND

+                ${CMAKE_COMMAND} -E make_directory

+                    ${CMAKE_BINARY_DIR}/${ASSET_DIR}

+            COMMAND

+                ${CMAKE_COMMAND} -E create_symlink

+                    ${PROJECT_SOURCE_DIR}/${ASSET}

+                    ${CMAKE_BINARY_DIR}/${ASSET}

+            VERBATIM

+        )

+        set_property(TARGET ${PROJECT_NAME}-assets APPEND PROPERTY

+            SOURCES ${CMAKE_BINARY_DIR}/${ASSET}

+        )

+        if(NOT ASSET_TEST)

+            install(

+                FILES

+                    ${PROJECT_SOURCE_DIR}/${ASSET}

+                DESTINATION

+                    ${CMAKE_INSTALL_DATADIR}/${CMAKE_PROJECT_NAME}/${ASSET_DIR}

+            )

+        endif()

+    endforeach()

+

+    ## Documentation

+    if(PROJECT_IS_TOP_LEVEL)

+        file(GLOB_RECURSE DOCS CONFIGURE_DEPENDS

+            RELATIVE "${PROJECT_SOURCE_DIR}"

+            doc/*

+        )

+        file(GLOB DOCS_ROOT CONFIGURE_DEPENDS

+            RELATIVE "${PROJECT_SOURCE_DIR}"

+            README*

+            LICENSE*

+            COPYING*

+            CHANGELOG*

+            CHANGES*

+            HISTORY*

+            NEWS*

+            RELEASES*

+            AUTHORS*

+            ACKNOWLEDGMENTS*

+            CONTRIBUTORS*

+            CONTRIBUTING*

+            CODE_OF_CONDUCT*

+            SECURITY*

+            SUPPORT*

+        )

+        list(APPEND DOCS ${DOCS_ROOT})

+        foreach(DOC ${DOCS})

+            get_filename_component(DOC_DIR ${DOC} DIRECTORY)

+            install(

+                FILES

+                    ${PROJECT_SOURCE_DIR}/${DOC}

+                DESTINATION

+                    ${CMAKE_INSTALL_DOCDIR}/${DOC_DIR}

+            )

+        endforeach()

+    endif()

+

+    ## Man pages

+    if(PROJECT_IS_TOP_LEVEL)

+        file(GLOB_RECURSE MANS CONFIGURE_DEPENDS

+            RELATIVE "${PROJECT_SOURCE_DIR}"

+            man/*

+        )

+        foreach(MAN ${MANS})

+            get_filename_component(MAN_DIR ${MAN} DIRECTORY)

+            install(

+                FILES

+                    ${PROJECT_SOURCE_DIR}/${MAN}

+                DESTINATION

+                    ${CMAKE_INSTALL_MANDIR}/${MAN_DIR}

+            )

+        endforeach()

+    endif()

+

+    ## Language version

+    set_target_properties(${BUILD_TARGETS} PROPERTIES

+        CXX_STANDARD          "${ARG_CXX_STANDARD}"

+        CXX_STANDARD_REQUIRED ON

+        CXX_EXTENSIONS        OFF

+    )

+

+    ## Build options

+    if(PROJECT_IS_TOP_LEVEL)

+        if(MSVC)

+            set(MSVC_OPTIONS)

+            if(MSVC_VERSION GREATER_EQUAL 1914)

+                set(MSVC_OPTIONS "/Zc:__cplusplus")

+            endif()

+            set(COMPILE_OPTIONS

+                /permissive-

+                /WX

+                /W4

+                ${MSVC_OPTIONS}

+            )

+        elseif("${CMAKE_CXX_COMPILER_ID}" MATCHES "GNU|.*Clang")

+            set(SANITIZE_OPTIONS)

+            if(PROJECT_IS_DEBUG AND NOT ARG_DISABLE_SANITIZERS)

+                set(SANITIZE_OPTIONS

+                    $<$<CONFIG:Debug>:

+                        -fno-omit-frame-pointer

+                        -fsanitize=address,leak,undefined

+                        -fsanitize=float-divide-by-zero

+                        -fsanitize=float-cast-overflow

+                        # -fsanitize=pointer-compare

+                        # -fsanitize=pointer-subtract

+                        # -fsanitize=implicit-conversion

+                        -fno-sanitize-recover=all

+                    >

+                )

+            endif()

+            set(WSHADOW_OPTION)

+            if(NOT ARG_DISABLE_WSHADOW)

+                set(WSHADOW_OPTION -Wshadow)

+            endif()

+            set(COMPILE_OPTIONS

+                -pedantic

+                -Werror # -Wfatal-errors

+                -Wall -Wextra

+                -Wno-missing-braces -Wmissing-field-initializers

+                -Wconversion -Wsign-conversion

+                -Wdouble-promotion

+                -Wimplicit-fallthrough

+                -Wvla

+                -Wzero-as-null-pointer-constant

+                -Weffc++

+                ${WSHADOW_OPTION}

+                ${SANITIZE_OPTIONS}

+            )

+            set(LINK_OPTIONS

+                ${SANITIZE_OPTIONS}

+            )

+            check_ipo_supported(RESULT INTERPROCEDURAL_OPTIMIZATION)

+        endif()

+        set_property(TARGET ${BUILD_TARGETS} APPEND PROPERTY

+            COMPILE_OPTIONS "${COMPILE_OPTIONS}"

+        )

+        set_property(TARGET ${BUILD_TARGETS} APPEND PROPERTY

+            LINK_OPTIONS "${LINK_OPTIONS}"

+        )

+        set_property(TARGET ${BUILD_TARGETS} APPEND PROPERTY

+            INTERPROCEDURAL_OPTIMIZATION "${INTERPROCEDURAL_OPTIMIZATION}"

+        )

+    endif()

+

+    ## Sanitizer environment variables

+    set(SAN_STRIP_PATH_PREFIX strip_path_prefix=${PROJECT_BINARY_DIR})

+    set(ASAN_OPTIONS  "${SAN_STRIP_PATH_PREFIX}")

+    set(LSAN_OPTIONS  "${SAN_STRIP_PATH_PREFIX}")

+    set(UBSAN_OPTIONS "${SAN_STRIP_PATH_PREFIX}")

+    file(GLOB ASAN_SUPPS  CONFIGURE_DEPENDS *.asan.supp)

+    file(GLOB LSAN_SUPPS  CONFIGURE_DEPENDS *.lsan.supp)

+    file(GLOB UBSAN_SUPPS CONFIGURE_DEPENDS *.ubsan.supp)

+    foreach(ASAN_SUPP ${ASAN_SUPPS})

+        set(ASAN_OPTIONS "${ASAN_OPTIONS},suppressions=${ASAN_SUPP}")

+    endforeach()

+    foreach(LSAN_SUPP ${LSAN_SUPPS})

+        set(LSAN_OPTIONS "${LSAN_OPTIONS},suppressions=${LSAN_SUPP}")

+    endforeach()

+    foreach(UBSAN_SUPP ${UBSAN_SUPPS})

+        set(UBSAN_OPTIONS "${UBSAN_OPTIONS},suppressions=${UBSAN_SUPP}")

+    endforeach()

+    # set(ASAN_OPTIONS "${ASAN_OPTIONS},detect_leaks=1")

+    # set(UBSAN_OPTIONS "${UBSAN_OPTIONS},print_stacktrace=1")

+    set_property(TEST ${TEST_TARGETS} APPEND PROPERTY

+        ENVIRONMENT

+            ASAN_OPTIONS=${ASAN_OPTIONS}

+            LSAN_OPTIONS=${LSAN_OPTIONS}

+            UBSAN_OPTIONS=${UBSAN_OPTIONS}

+    )

+

+    ## Tools

+    if(PROJECT_IS_TOP_LEVEL AND PROJECT_IS_DEBUG)

+        find_program(CPPCHECK             cppcheck)

+        find_program(CLANG_TIDY           clang-tidy)

+        find_program(INCLUDE_WHAT_YOU_USE include-what-you-use)

+        set(CPPCHECK_OPTIONS)

+        set(IWYU_OPTIONS)

+        file(GLOB CPPCHECK_SUPPS CONFIGURE_DEPENDS *.cppcheck.supp)

+        file(GLOB IWYU_IMPS      CONFIGURE_DEPENDS *.iwyu.imp)

+        if("${CMAKE_CXX_COMPILER_ID}" MATCHES ".*Clang")

+            set(CPPCHECK_OPTIONS --clang)

+        endif()

+        foreach(CPPCHECK_SUPP ${CPPCHECK_SUPPS})

+            set(CPPCHECK_OPTIONS "${CPPCHECK_OPTIONS}"

+                "--suppressions-list=${CPPCHECK_SUPP}"

+            )

+        endforeach()

+        foreach(IWYU_IMP ${IWYU_IMPS})

+            set(IWYU_OPTIONS "${IWYU_OPTIONS}"

+                "-Xiwyu" "--mapping_file=${IWYU_IMP}"

+            )

+        endforeach()

+        if(CPPCHECK AND NOT ARG_DISABLE_CPPCHECK)

+            set(CXX_CPPCHECK ${CPPCHECK}

+                --error-exitcode=1

+                --enable=warning,style

+                --inline-suppr

+                --template=gcc

+                "--cppcheck-build-dir=${CMAKE_BINARY_DIR}/cppcheck"

+                "--std=c++${ARG_CXX_STANDARD}"

+                ${CPPCHECK_OPTIONS}

+            )

+        endif()

+        if(CLANG_TIDY AND NOT ARG_DISABLE_CLANG_TIDY)

+            set(CXX_CLANG_TIDY ${CLANG_TIDY}

+                --extra-arg=-Wno-unknown-warning-option

+                --extra-arg=-Wno-ignored-optimization-argument

+            )

+        endif()